Using An Arduino to Acquire Sensor Data From The MPU6050 Motion Sensor.

The Arduino part of this project was almost entirely based on standard Arduino community libraries. The use of the Arduino, and associated libraries, was simply to acquire raw data, from the MPU6050 motion sensor, and relay it through the serial (USB) interface to a host (laptop) computer. Where the real analysis and modeling takes place.

So basically the public software implementation was slightly modified to provide only the raw acceleration, raw rotation (gyro), raw 'DMP' quaternion and the core temperature. The rest of the processing, for now, is up to the host.

//-----------------------------------------------------------------------------
// smegsense_6050.ino
//
// I2C device class (I2Cdev) demonstration Arduino sketch for MPU6050 class using DMP (MotionApps v2.0)
// 6/21/2012 by Jeff Rowberg <jeff@rowberg.net>
// Updates should (hopefully) always be available at https://github.com/jrowberg/i2cdevlib
//
// Changelog:
//      2013-05-08 - added seamless Fastwire support
//                 - added note about gyro calibration
//      2012-06-21 - added note about Arduino 1.0.1 + Leonardo compatibility error
//      2012-06-20 - improved FIFO overflow handling and simplified read process
//      2012-06-19 - completely rearranged DMP initialization code and simplification
//      2012-06-13 - pull gyro and accel data from FIFO packet instead of reading directly
//      2012-06-09 - fix broken FIFO read sequence and change interrupt detection to RISING
//      2012-06-05 - add gravity-compensated initial reference frame acceleration output
//                 - add 3D math helper file to DMP6 example sketch
//                 - add Euler output and Yaw/Pitch/Roll output formats
//      2012-06-04 - remove accel offset clearing for better results (thanks Sungon Lee)
//      2012-06-01 - fixed gyro sensitivity to be 2000 deg/sec instead of 250
//      2012-05-30 - basic DMP initialization working
/* ============================================
I2Cdev device library code is placed under the MIT license
Copyright (c) 2012 Jeff Rowberg

Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the "Software"), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in
all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
THE SOFTWARE.
===============================================
*/
// I2Cdev and MPU6050 must be installed as libraries, or else the .cpp/.h files
// for both classes must be in the include path of your project
#include "I2Cdev.h"

#include "MPU6050_6Axis_MotionApps20.h"
//#include "MPU6050.h" // not necessary if using MotionApps include file

// Arduino Wire library is required if I2Cdev I2CDEV_ARDUINO_WIRE implementation
// is used in I2Cdev.h
#if I2CDEV_IMPLEMENTATION == I2CDEV_ARDUINO_WIRE
    #include "Wire.h"
#endif

// class default I2C address is 0x68
// specific I2C addresses may be passed as a parameter here
// AD0 low = 0x68 (default for SparkFun breakout and InvenSense evaluation board)
// AD0 high = 0x69
MPU6050 mpu;
//MPU6050 mpu(0x69); // <-- use for AD0 high

/* =========================================================================
   NOTE: In addition to connection 3.3v, GND, SDA, and SCL, this sketch
   depends on the MPU-6050's INT pin being connected to the Arduino's
   external interrupt #0 pin. On the Arduino Uno and Mega 2560, this is
   digital I/O pin 2.
 * ========================================================================= */

/* =========================================================================
   NOTE: Arduino v1.0.1 with the Leonardo board generates a compile error
   when using Serial.write(buf, len). The Teapot output uses this method.
   The solution requires a modification to the Arduino USBAPI.h file, which
   is fortunately simple, but annoying. This will be fixed in the next IDE
   release. For more info, see these links:

   http://arduino.cc/forum/index.php/topic,109987.0.html
   http://code.google.com/p/arduino/issues/detail?id=958
 * ========================================================================= */

#define LED_PIN 13 // (Arduino is 13, Teensy is 11, Teensy++ is 6)
bool blinkState = false;

// MPU control/status vars
static bool      dmpReady = false; // set true if DMP init was successful
volatile uint8_t mpuIntStatus;     // holds actual interrupt status byte from MPU
static uint8_t   devStatus;        // return status after each device operation (!0 = error)
static uint16_t  packetSize;       // expected DMP packet size (default is 42 bytes)
static uint16_t  fifoCount;        // count of all bytes currently in FIFO
static uint8_t   fifoBuffer[64];   // FIFO storage buffer
static int16_t   temperature;      // Sensor die temperature.

// orientation/motion vars
VectorInt16 aa;         // [x, y, z] accel sensor measurements
VectorInt16 ag;         // [x, y, z] gyro sensor measurements
int16_t qraw[4];        // Raw DMP Quaternion.

static char sbuf[80]; // Serial line buffer.

// ================================================================
// ===               INTERRUPT DETECTION ROUTINE                ===
// ================================================================

volatile bool mpuInterrupt = false; // indicates whether MPU interrupt pin has gone high
void dmpDataReady() {
    mpuInterrupt = true;
}

// ================================================================
// ===                      INITIAL SETUP                       ===
// ================================================================

void setup() {
    // join I2C bus (I2Cdev library doesn't do this automatically)
    #if I2CDEV_IMPLEMENTATION == I2CDEV_ARDUINO_WIRE
        Wire.begin();
        TWBR = 24; // 400kHz I2C clock (200kHz if CPU is 8MHz)
    #elif I2CDEV_IMPLEMENTATION == I2CDEV_BUILTIN_FASTWIRE
        Fastwire::setup(400, true);
    #endif

    // initialize serial communication
    // (115200 chosen because it is required for Teapot Demo output, but it's
    // really up to you depending on your project)
    Serial.begin(230400);
    while (!Serial); // wait for Leonardo enumeration, others continue immediately

    // NOTE: 8MHz or slower host processors, like the Teensy @ 3.3v or Ardunio
    // Pro Mini running at 3.3v, cannot handle this baud rate reliably due to
    // the baud timing being too misaligned with processor ticks. You must use
    // 38400 or slower in these cases, or use some kind of external separate
    // crystal solution for the UART timer.

    // initialize device
    Serial.print(F("Initializing I2C devices...\n"));
    mpu.initialize();

    // verify connection
    Serial.print(F("Testing device connections...\n"));
    Serial.print(mpu.testConnection() ? F("MPU6050 connection successful\n") : F("MPU6050 connection failed\n"));

    // wait for ready
    Serial.print(F("Waiting for any character to continue.\n.\n"));
    while (Serial.available() && Serial.read()); // empty buffer
    while (!Serial.available());                 // wait for data
    while (Serial.available() && Serial.read()); // empty buffer again

    // load and configure the DMP
    Serial.println(F("Initializing DMP..."));
    devStatus = mpu.dmpInitialize();

    // supply your own gyro offsets here, scaled for min sensitivity
    mpu.setXGyroOffset(220);
    mpu.setYGyroOffset(76);
    mpu.setZGyroOffset(-85);
    mpu.setZAccelOffset(898); // 1688 factory default for my test chip

    Serial.print("Output FIFO size - ");
    Serial.print(mpu.dmpGetFIFOPacketSize());
    Serial.print("\n");

    // make sure it worked (returns 0 if so)
    if (devStatus == 0) {
        // turn on the DMP, now that it's ready
        Serial.print(F("Enabling DMP...\n"));
        mpu.setDMPEnabled(true);

        // enable Arduino interrupt detection
        Serial.print(F("Enabling interrupt detection (Arduino external interrupt 0)...\n"));
        attachInterrupt(0, dmpDataReady, RISING);
        mpuIntStatus = mpu.getIntStatus();

        // set our DMP Ready flag so the main loop() function knows it's okay to use it
        Serial.print(F("DMP ready! Waiting for first interrupt...\n"));
        dmpReady = true;

        // get expected DMP packet size for later comparison
        packetSize = mpu.dmpGetFIFOPacketSize();
    } else {
        // ERROR!
        // 1 = initial memory load failed
        // 2 = DMP configuration updates failed
        // (if it's going to break, usually the code will be 1)
        Serial.print(F("DMP Initialization failed (code "));
        Serial.print(devStatus);
        Serial.print(F(")\n"));
    }

    // configure LED for output
    pinMode(LED_PIN, OUTPUT);
}

// ================================================================
// ===                    MAIN PROGRAM LOOP                     ===
// ================================================================

#define CHANGE_GATE 10
static uint8_t gate = 0;

void loop() {
  // if programming failed, don't try to do anything
  if (!dmpReady) return;

  // wait for MPU interrupt or extra packet(s) available
  while (!mpuInterrupt && fifoCount < packetSize)
  {
    // other program behavior stuff here ...
    //  if you are really paranoid you can frequently test in between other
    //  stuff to see if mpuInterrupt is true, and if so, "break;" from the
    //  while() loop to immediately process the MPU data...
    if(gate >= CHANGE_GATE)
    {
      gate = 0;
      // blink LED to indicate activity
      blinkState = !blinkState;
      digitalWrite(LED_PIN, blinkState);
    }
  }
  // reset interrupt flag and get INT_STATUS byte
  mpuInterrupt = false;
  mpuIntStatus = mpu.getIntStatus();
  // Get Die temperature.
  temperature = mpu.getTemperature();
  // get current FIFO count
  fifoCount = mpu.getFIFOCount();
  // check for overflow (this should never happen unless our code is too inefficient)
  if ((mpuIntStatus & 0x10) || fifoCount == 1024)
  {
    // reset so we can continue cleanly
    mpu.resetFIFO();
    Serial.println(F("FIFO overflow!"));
  }
  // otherwise, check for DMP data ready interrupt (this should happen frequently)
  else if (mpuIntStatus & 0x02)
  {
    // wait for correct available data length, should be a VERY short wait
    while (fifoCount < packetSize)
    {
      fifoCount = mpu.getFIFOCount();
    }
    // read a packet from FIFO
    mpu.getFIFOBytes(fifoBuffer, packetSize);
    // track FIFO count here in case there is > 1 packet available
    // (this lets us immediately read more without waiting for an interrupt)
    fifoCount -= packetSize;
    // Report raw Acceleration values.
    mpu.dmpGetAccel(&aa, fifoBuffer);
    sprintf(sbuf, "araw %i %i %i \n", aa.x, aa.y, aa.z);
    Serial.print(sbuf);
    // Report raw Gyro rates.
    mpu.dmpGetGyro(&ag, fifoBuffer);
    sprintf(sbuf, "graw %i %i %i \n", ag.x, ag.y, ag.z);
    Serial.print(sbuf);
    // Report raw Quaternian orientation.
    mpu.dmpGetQuaternion(qraw, fifoBuffer);
    sprintf(sbuf, "qraw %i %i %i %i \n", qraw[0], qraw[1], qraw[2], qraw[3]);
    Serial.print(sbuf);
    // Report raw sensor DIE Temperature.
    sprintf(sbuf, "temp %i \n", temperature);
    Serial.print(sbuf);
    // Signal end of packet.
    Serial.print(".\n");
    // Throttle LED blink rate.
    gate += 1;
  }
}
//-----------------------------------------------------------------------------
// end: smegsense_6050.ino

The real goal here is to do quicker modeling and simulation hopefuly to help develop algorithms that can be easily implemented in the Arduino specifically for servo (feedback : rate and position) control.

Even with the limitations of the 8-bit AVR processor it is still possible using fixed-point (integer only) math to properly close a high-bandwidth servo loop. It practically only takes a few hundred integer math operations at say maybe 50 - 100 times per/second. The trick would be synchronizing the week IIC interface with the realtime requirement of the processing.

A First Attempt At Visualizing The Data.

The raw sensor data acquired by the computer was processed and displayed as both raw and rendered (poorly) as a 3D object. Normally I work only with 2D windows. At a very low level. This was my first attempt at placing a GL context window within a normal window shared by other normal windows.

In the following demonstrations the sensor data was processed and then displayed in graph/chart form and in a 3D form. Additionally some raw data and the DIE temperature is displayed at the bottom of the frame.

Since this is my first 3D program I could not resist using the standard teapot as the demonstration model.

The next test represents a 3-gimbal (3D) system. The three gimbals represent the angular position of the sensor in the different axis. The unfinished goal here is to place an object in the center of the gimbals that is stabilized so that it represents a vector that always points to the reference coordinates. Perfect for any guidence system or just stabilizing the lights on your off-road vehicle of choice.

A little more primative gyroscope view.

The final attempt was an artificial horizon. There is no change of graphics since I am not a 3D programmer. It would make more sense if imagery of the actual sensor could be viewed alongside the modeling. Maybe next upgrade.

Additional Resources That May Be Useful...

MPU6050 Data Sheet...

MPU6050 Detailed Register Description...